假如A1 A2 A3 A4 A5 A6
1 1 0 1 0 2
我要假設A1跟A2如果等於2的話..我要加1 但A1跟A2 如果=1的話就是0
以此類推...就是1 2 是一組 3 4 是一組..=2 就+1.
如此圖我要的答案是2 因為A1 A2 等於2 A5 A6等於2..有兩個2
請問要怎麼寫才能成立~~感謝~
抱歉。小弟表達能力不足。。
我的意思是要算總共有幾組2。。
A1a2是1組。。a3a4是1組 a5a6是一組。內容只有1或0
假如3組是a1+a2=2 a3+a4=2 a5+a6=2
那我要的答案是3。。因為有3組2的答案。。如果不等於2就不要算
========================================
方法1.
B1公式: (B1輸入完公式後再往下拖拉到B欄最後一筆資料所在的列進行複製)
=IF(MOD(ROW(),2)=1, $A1+$A2, "")
F1公式:
=COUNTIF($B$1:$B$10, 2)
========================================
方法2.
D2公式:
=SUMPRODUCT(--(OFFSET(INDIRECT($D$1),0,0,ROWS(INDIRECT($D$1))-1)+OFFSET(INDIRECT($D$1),1,0,ROWS(INDIRECT($D$1))-1)=2),--(MOD(ROW(OFFSET(INDIRECT($D$1),0,0,ROWS(INDIRECT($D$1))-1)),2)=1))
或
=SUMPRODUCT(--(INDIRECT($D$1)+OFFSET(INDIRECT($D$1),1,0)=2),--(MOD(ROW(INDIRECT($D$1)),2)=1))
只有D2需要輸入公式,而日後只要改變D1的參照範圍即可.
abodmq wrote:
請問如果資料要轉橫向輸入??是要修改哪一句~~
似乎只能直向輸入~~
如要B2到BO2....
橫向資料的話,如參照為--> B2:BO2
則可以改成如下的公式:
=SUMPRODUCT(--(OFFSET(B2:BO2,0,0,,COLUMNS(B2:BO2)-1)+OFFSET(B2:BO2,0,1,,COLUMNS(B2:BO2)-1)=2),--(MOD(COLUMN(OFFSET(B2:BO2,0,0,,COLUMNS(B2:BO2)-1)),2)=0))
或
=SUMPRODUCT(--(B2:BO2+OFFSET(B2:BO2,0,1)=2),--(MOD(COLUMN(B2:BO2),2)=0))
PS:因為開頭欄為 B(即第2欄),是屬"雙數"欄,
所以要用 MOD(COLUMN(資料範圍參照),2)=0 來代入公式中,
若如果,開頭欄為"單數"欄的話,
則改用 MOD(COLUMN(資料範圍參照),2)=1 來代入公式中.
內文搜尋
從 APP 打開
X